| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
This chapter describes the compilation model used by GNAT. Although similar to that used by other languages, such as C and C++, this model is substantially different from the traditional Ada compilation models, which are based on a library. The model is initially described without reference to the library-based model. If you have not previously used an Ada compiler, you need only read the first part of this chapter. The last section describes and discusses the differences between the GNAT model and the traditional Ada compiler models. If you have used other Ada compilers, this section will help you to understand those differences, and the advantages of the GNAT model.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Ada source programs are represented in standard text files, using Latin-1 coding. Latin-1 is an 8-bit code that includes the familiar 7-bit ASCII set, plus additional characters used for representing foreign languages (see section 2.2 Foreign Language Representation for support of non-USA character sets). The format effector characters are represented using their standard ASCII encodings, as follows:
VT
16#0B#
HT
16#09#
CR
16#0D#
LF
16#0A#
FF
16#0C#
Source files are in standard text file format. In addition, GNAT will
recognize a wide variety of stream formats, in which the end of
physical lines is marked by any of the following sequences:
LF, CR, CR-LF, or LF-CR. This is useful
in accommodating files that are imported from other operating systems.
The end of a source file is normally represented by the physical end of
file. However, the control character 16#1A# (SUB) is also
recognized as signalling the end of the source file. Again, this is
provided for compatibility with other operating systems where this
code is used to represent the end of file.
Each file contains a single Ada compilation unit, including any pragmas associated with the unit. For example, this means you must place a package declaration (a package spec) and the corresponding body in separate files. An Ada compilation (which is a sequence of compilation units) is represented using a sequence of files. Similarly, you will place each subunit or child unit in a separate file.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
GNAT supports the standard character sets defined in Ada 95 as well as several other non-standard character sets for use in localized versions of the compiler (see section 3.2.11 Character Set Control).
2.2.1 Latin-1 2.2.2 Other 8-Bit Codes 2.2.3 Wide Character Encodings
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
The basic character set is Latin-1. This character set is defined by ISO
standard 8859, part 1. The lower half (character codes 16#00#
... 16#7F#) is identical to standard ASCII coding, but the upper half
is used to represent additional characters. These include extended letters
used by European languages, such as French accents, the vowels with umlauts
used in German, and the extra letter A-ring used in Swedish.
For a complete list of Latin-1 codes and their encodings, see the source
file of library unit Ada.Characters.Latin_1 in file
`a-chlat1.ads'.
You may use any of these extended characters freely in character or
string literals. In addition, the extended characters that represent
letters can be used in identifiers.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
GNAT also supports several other 8-bit coding schemes:
For precise data on the encodings permitted, and the uppercase and lowercase equivalences that are recognized, see the file `csets.adb' in the GNAT compiler sources. You will need to obtain a full source release of GNAT to obtain this file.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
GNAT allows wide character codes to appear in character and string literals, and also optionally in identifiers, by means of the following possible encoding schemes:
ESC a b c d |
Where a, b, c, d are the four hexadecimal
characters (using uppercase letters) of the wide character code. For
example, ESC A345 is used to represent the wide character with code
16#A345#.
This scheme is compatible with use of the full Wide_Character set.
16#abcd# where the upper bit is on
(in other words, "a" is in the range 8-F) is represented as two bytes,
16#ab# and 16#cd#. The second byte cannot be a format control
character, but is not required to be in the upper half. This method can
be also used for shift-JIS or EUC, where the internal coding matches the
external coding.
16#ab# and
16#cd#, with the restrictions described for upper-half encoding as
described above. The internal character code is the corresponding JIS
character according to the standard algorithm for Shift-JIS
conversion. Only characters defined in the JIS code set table can be
used with this encoding method.
16#ab# and
16#cd#, with both characters being in the upper half. The internal
character code is the corresponding JIS character according to the EUC
encoding algorithm. Only characters defined in the JIS code set table
can be used with this encoding method.
16#0000#-16#007f#: 2#0xxxxxxx# 16#0080#-16#07ff#: 2#110xxxxx# 2#10xxxxxx# 16#0800#-16#ffff#: 2#1110xxxx# 2#10xxxxxx# 2#10xxxxxx# |
where the xxx bits correspond to the left-padded bits of the 16-bit character value. Note that all lower half ASCII characters are represented as ASCII bytes and all upper half characters and other wide characters are represented as sequences of upper-half (The full UTF-8 scheme allows for encoding 31-bit characters as 6-byte sequences, but in this implementation, all UTF-8 sequences of four or more bytes length will be treated as illegal).
[ " a b c d " ] |
Where a, b, c, d are the four hexadecimal
characters (using uppercase letters) of the wide character code. For
example, ["A345"] is used to represent the wide character with code
16#A345#. It is also possible (though not required) to use the
Brackets coding for upper half characters. For example, the code
16#A3# can be represented as ["A3"].
This scheme is compatible with use of the full Wide_Character set, and is also the method used for wide character encoding in the standard ACVC (Ada Compiler Validation Capability) test suite distributions.
Note: Some of these coding schemes do not permit the full use of the Ada 95 character set. For example, neither Shift JIS, nor EUC allow the use of the upper half of the Latin-1 set.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
The default file name is determined by the name of the unit that the file contains. The name is formed by taking the full expanded name of the unit and replacing the separating dots with hyphens and using lowercase for all letters.
An exception arises if the file name generated by the above rules starts with one of the characters a,g,i, or s, and the second character is a minus. In this case, the character tilde is used in place of the minus. The reason for this special rule is to avoid clashes with the standard names for child units of the packages System, Ada, Interfaces, and GNAT, which use the prefixes s- a- i- and g- respectively.
The file extension is `.ads' for a spec and `.adb' for a body. The following list shows some examples of these rules.
Following these rules can result in excessively long
file names if corresponding
unit names are long (for example, if child units or subunits are
heavily nested). An option is available to shorten such long file names
(called file name "krunching"). This may be particularly useful when
programs being developed with GNAT are to be used on operating systems
with limited file name lengths. See section 15.2 Using gnatkr.
Of course, no file shortening algorithm can guarantee uniqueness over
all possible unit names; if file name krunching is used, it is your
responsibility to ensure no name clashes occur. Alternatively you
can specify the exact file names that you want used, as described
in the next section. Finally, if your Ada programs are migrating from a
compiler with a different naming convention, you can use the gnatchop
utility to produce source files that follow the GNAT naming conventions.
(For details see section 8. Renaming Files Using gnatchop.)
Note: in the case of Windows NT/XP or OpenVMS operating
systems, case is not significant. So for example on Windows XP
if the canonical name is main-sub.adb, you can use the file name
Main-Sub.adb instead. However, case is significant for other
operating systems, so for example, if you want to use other than
canonically cased file names on a Unix system, you need to follow
the procedures described in the next section.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
In the previous section, we have described the default rules used by GNAT to determine the file name in which a given unit resides. It is often convenient to follow these default rules, and if you follow them, the compiler knows without being explicitly told where to find all the files it needs.
However, in some cases, particularly when a program is imported from another Ada compiler environment, it may be more convenient for the programmer to specify which file names contain which units. GNAT allows arbitrary file names to be used by means of the Source_File_Name pragma. The form of this pragma is as shown in the following examples:
pragma Source_File_Name (My_Utilities.Stacks, Spec_File_Name => "myutilst_a.ada"); pragma Source_File_name (My_Utilities.Stacks, Body_File_Name => "myutilst.ada"); |
As shown in this example, the first argument for the pragma is the unit name (in this example a child unit). The second argument has the form of a named association. The identifier indicates whether the file name is for a spec or a body; the file name itself is given by a string literal.
The source file name pragma is a configuration pragma, which means that normally it will be placed in the `gnat.adc' file used to hold configuration pragmas that apply to a complete compilation environment. For more details on how the `gnat.adc' file is created and used see 9.1 Handling of Configuration Pragmas.
GNAT allows completely arbitrary file names to be specified using the
source file name pragma. However, if the file name specified has an
extension other than `.ads' or `.adb' it is necessary to use
a special syntax when compiling the file. The name in this case must be
preceded by the special sequence -x followed by a space and the name
of the language, here ada, as in:
$ gcc -c -x ada peculiar_file_name.sim |
gnatmake handles non-standard file names in the usual manner (the
non-standard file name for the main program is simply used as the
argument to gnatmake). Note that if the extension is also non-standard,
then it must be included in the gnatmake command, it may not be omitted.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
In the previous section, we described the use of the Source_File_Name
pragma to allow arbitrary names to be assigned to individual source files.
However, this approach requires one pragma for each file, and especially in
large systems can result in very long `gnat.adc' files, and also create
a maintenance problem.
GNAT also provides a facility for specifying systematic file naming schemes
other than the standard default naming scheme previously described. An
alternative scheme for naming is specified by the use of
Source_File_Name pragmas having the following format:
pragma Source_File_Name ( Spec_File_Name => FILE_NAME_PATTERN [,Casing => CASING_SPEC] [,Dot_Replacement => STRING_LITERAL]); pragma Source_File_Name ( Body_File_Name => FILE_NAME_PATTERN [,Casing => CASING_SPEC] [,Dot_Replacement => STRING_LITERAL]); pragma Source_File_Name ( Subunit_File_Name => FILE_NAME_PATTERN [,Casing => CASING_SPEC] [,Dot_Replacement => STRING_LITERAL]); FILE_NAME_PATTERN ::= STRING_LITERAL CASING_SPEC ::= Lowercase | Uppercase | Mixedcase |
The FILE_NAME_PATTERN string shows how the file name is constructed.
It contains a single asterisk character, and the unit name is substituted
systematically for this asterisk. The optional parameter
Casing indicates
whether the unit name is to be all upper-case letters, all lower-case letters,
or mixed-case. If no
Casing parameter is used, then the default is all
lower-case.
The optional Dot_Replacement string is used to replace any periods
that occur in subunit or child unit names. If no Dot_Replacement
argument is used then separating dots appear unchanged in the resulting
file name.
Although the above syntax indicates that the
Casing argument must appear
before the Dot_Replacement argument, but it
is also permissible to write these arguments in the opposite order.
As indicated, it is possible to specify different naming schemes for
bodies, specs, and subunits. Quite often the rule for subunits is the
same as the rule for bodies, in which case, there is no need to give
a separate Subunit_File_Name rule, and in this case the
Body_File_name rule is used for subunits as well.
The separate rule for subunits can also be used to implement the rather unusual case of a compilation environment (e.g. a single directory) which contains a subunit and a child unit with the same unit name. Although both units cannot appear in the same partition, the Ada Reference Manual allows (but does not require) the possibility of the two units coexisting in the same environment.
The file name translation works in the following steps:
Source_File_Name pragma for the given unit,
then this is always used, and any general pattern rules are ignored.
Source_File_Name pragma that applies to
the unit, then the resulting file name will be used if the file exists. If
more than one pattern matches, the latest one will be tried first, and the
first attempt resulting in a reference to a file that exists will be used.
Source_File_Name pragma that applies to the unit
for which the corresponding file exists, then the standard GNAT default
naming rules are used.
As an example of the use of this mechanism, consider a commonly used scheme in which file names are all lower case, with separating periods copied unchanged to the resulting file name, and specs end with `.1.ada', and bodies end with `.2.ada'. GNAT will follow this scheme if the following two pragmas appear:
pragma Source_File_Name (Spec_File_Name => "*.1.ada"); pragma Source_File_Name (Body_File_Name => "*.2.ada"); |
The default GNAT scheme is actually implemented by providing the following default pragmas internally:
pragma Source_File_Name (Spec_File_Name => "*.ads", Dot_Replacement => "-"); pragma Source_File_Name (Body_File_Name => "*.adb", Dot_Replacement => "-"); |
Our final example implements a scheme typically used with one of the Ada 83 compilers, where the separator character for subunits was "__" (two underscores), specs were identified by adding `_.ADA', bodies by adding `.ADA', and subunits by adding `.SEP'. All file names were upper case. Child units were not present of course since this was an Ada 83 compiler, but it seems reasonable to extend this scheme to use the same double underscore separator for child units.
pragma Source_File_Name (Spec_File_Name => "*_.ADA", Dot_Replacement => "__", Casing = Uppercase); pragma Source_File_Name (Body_File_Name => "*.ADA", Dot_Replacement => "__", Casing = Uppercase); pragma Source_File_Name (Subunit_File_Name => "*.SEP", Dot_Replacement => "__", Casing = Uppercase); |
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
An Ada program consists of a set of source files, and the first step in compiling the program is to generate the corresponding object files. These are generated by compiling a subset of these source files. The files you need to compile are the following:
The preceding rules describe the set of files that must be compiled to generate the object files for a program. Each object file has the same name as the corresponding source file, except that the extension is `.o' as usual.
You may wish to compile other files for the purpose of checking their syntactic and semantic correctness. For example, in the case where a package has a separate spec and body, you would not normally compile the spec. However, it is convenient in practice to compile the spec to make sure it is error-free before compiling clients of this spec, because such compilations will fail if there is an error in the spec.
GNAT provides an option for compiling such files purely for the purposes of checking correctness; such compilations are not required as part of the process of building a program. To compile a file in this checking mode, use the `-gnatc' switch.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
A given object file clearly depends on the source file which is compiled
to produce it. Here we are using depends in the sense of a typical
make utility; in other words, an object file depends on a source
file if changes to the source file require the object file to be
recompiled.
In addition to this basic dependency, a given object may depend on
additional source files as follows:
with's a unit X, the object file
depends on the file containing the spec of unit X. This includes
files that are with'ed implicitly either because they are parents
of with'ed child units or they are run-time units required by the
language constructs used in a particular unit.
Inline applies and inlining is activated with the
`-gnatn' switch, the object file depends on the file containing the
body of this subprogram as well as on the file containing the spec. Note
that for inlining to actually occur as a result of the use of this switch,
it is necessary to compile in optimizing mode.
The use of `-gnatN' activates a more extensive inlining optimization that is performed by the front end of the compiler. This inlining does not require that the code generation be optimized. Like `-gnatn', the use of this switch generates additional dependencies. Note that `-gnatN' automatically implies `-gnatn' so it is not necessary to specify both options.
These rules are applied transitively: if unit A with's
unit B, whose elaboration calls an inlined procedure in package
C, the object file for unit A will depend on the body of
C, in file `c.adb'.
The set of dependent files described by these rules includes all the files on which the unit is semantically dependent, as described in the Ada 95 Language Reference Manual. However, it is a superset of what the ARM describes, because it includes generic, inline, and subunit dependencies.
An object file must be recreated by recompiling the corresponding source
file if any of the source files on which it depends are modified. For
example, if the make utility is used to control compilation,
the rule for an Ada object file must mention all the source files on
which the object file depends, according to the above definition.
The determination of the necessary
recompilations is done automatically when one uses gnatmake.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Each compilation actually generates two output files. The first of these is the normal object file that has a `.o' extension. The second is a text file containing full dependency information. It has the same name as the source file, but an `.ali' extension. This file is known as the Ada Library Information (`ALI') file. The following information is contained in the `ALI' file.
gcc command for the compilation
Pure).
with'ed units, including presence of
Elaborate or Elaborate_All pragmas.
Linker_Options pragmas used in the unit
Body_Version or Version
attributes in the unit.
gnatxref and gnatfind to
provide cross-reference information.
For a full detailed description of the format of the `ALI' file,
see the source of the body of unit Lib.Writ, contained in file
`lib-writ.adb' in the GNAT compiler sources.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
When using languages such as C and C++, once the source files have been compiled the only remaining step in building an executable program is linking the object modules together. This means that it is possible to link an inconsistent version of a program, in which two units have included different versions of the same header.
The rules of Ada do not permit such an inconsistent program to be built. For example, if two clients have different versions of the same package, it is illegal to build a program containing these two clients. These rules are enforced by the GNAT binder, which also determines an elaboration order consistent with the Ada rules.
The GNAT binder is run after all the object files for a program have been created. It is given the name of the main program unit, and from this it determines the set of units required by the program, by reading the corresponding ALI files. It generates error messages if the program is inconsistent or if no valid order of elaboration exists.
If no errors are detected, the binder produces a main program, in Ada by default, that contains calls to the elaboration procedures of those compilation unit that require them, followed by a call to the main program. This Ada program is compiled to generate the object file for the main program. The name of the Ada file is `b~xxx.adb' (with the corresponding spec `b~xxx.ads') where xxx is the name of the main program unit.
Finally, the linker is used to build the resulting executable program, using the object from the main program from the bind step as well as the object files for the Ada units of the program.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
This section describes how to develop a mixed-language program, specifically one that comprises units in both Ada and C.
2.10.1 Interfacing to C 2.10.2 Calling Conventions
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
extern statements in C, for instance, and the
Import, Export, and Convention pragmas in Ada. For
a full treatment of these topics, read Appendix B, section 1 of the Ada
95 Language Reference Manual.
There are two ways to build a program using GNAT that contains some Ada sources and some foreign language sources, depending on whether or not the main subprogram is written in Ada. Here is a source example with the main subprogram in Ada:
/* file1.c */
#include <stdio.h>
void print_num (int num)
{
printf ("num is %d.\n", num);
return;
}
/* file2.c */
/* num_from_Ada is declared in my_main.adb */
extern int num_from_Ada;
int get_num (void)
{
return num_from_Ada;
}
|
-- my_main.adb procedure My_Main is -- Declare then export an Integer entity called num_from_Ada My_Num : Integer := 10; pragma Export (C, My_Num, "num_from_Ada"); -- Declare an Ada function spec for Get_Num, then use -- C function get_num for the implementation. function Get_Num return Integer; pragma Import (C, Get_Num, "get_num"); -- Declare an Ada procedure spec for Print_Num, then use -- C function print_num for the implementation. procedure Print_Num (Num : Integer); pragma Import (C, Print_Num, "print_num"); begin Print_Num (Get_Num); end My_Main; |
gcc -c file1.c gcc -c file2.c |
gnatmake -c my_main.adb |
gnatbind my_main.ali |
gnatlink my_main.ali file1.o file2.o |
The last three steps can be grouped in a single command:
gnatmake my_main.adb -largs file1.o file2.o |
If the main program is in a language other than Ada, then you may have more than one entry point into the Ada subsystem. You must use a special binder option to generate callable routines that initialize and finalize the Ada units (see section 4.2.5 Binding with Non-Ada Main Programs). Calls to the initialization and finalization routines must be inserted in the main program, or some other appropriate point in the code. The call to initialize the Ada units must occur before the first Ada subprogram is called, and the call to finalize the Ada units must occur after the last Ada subprogram returns. The binder will place the initialization and finalization subprograms into the `b~xxx.adb' file where they can be accessed by your C sources. To illustrate, we have the following example:
/* main.c */
extern void adainit (void);
extern void adafinal (void);
extern int add (int, int);
extern int sub (int, int);
int main (int argc, char *argv[])
{
int a = 21, b = 7;
adainit();
/* Should print "21 + 7 = 28" */
printf ("%d + %d = %d\n", a, b, add (a, b));
/* Should print "21 - 7 = 14" */
printf ("%d - %d = %d\n", a, b, sub (a, b));
adafinal();
}
|
-- unit1.ads
package Unit1 is
function Add (A, B : Integer) return Integer;
pragma Export (C, Add, "add");
end Unit1;
-- unit1.adb
package body Unit1 is
function Add (A, B : Integer) return Integer is
begin
return A + B;
end Add;
end Unit1;
-- unit2.ads
package Unit2 is
function Sub (A, B : Integer) return Integer;
pragma Export (C, Sub, "sub");
end Unit2;
-- unit2.adb
package body Unit2 is
function Sub (A, B : Integer) return Integer is
begin
return A - B;
end Sub;
end Unit2;
|
gcc -c main.c |
gnatmake -c unit1.adb gnatmake -c unit2.adb |
gnatbind -n unit1.ali unit2.ali |
gnatlink unit2.ali main.o -o exec_file |
This procedure yields a binary executable called `exec_file'.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Ada
Note that in the case of GNAT running on a platform that supports DEC Ada 83, a higher degree of compatibility can be guaranteed, and in particular records are layed out in an identical manner in the two compilers. Note also that if output from two different compilers is mixed, the program is responsible for dealing with elaboration issues. Probably the safest approach is to write the main program in the version of Ada other than GNAT, so that it takes care of its own elaboration requirements, and then call the GNAT-generated adainit procedure to ensure elaboration of the GNAT components. Consult the documentation of the other Ada compiler for further details on elaboration.
However, it is not possible to mix the tasking run time of GNAT and DEC Ada 83, All the tasking operations must either be entirely within GNAT compiled sections of the program, or entirely within DEC Ada 83 compiled sections of the program.
Assembler
Asm
COBOL
C
C varargs function
varargs allows a function to take a variable number of
arguments. There is no direct equivalent in this to Ada. One
approach that can be used is to create a C wrapper for each
different profile and then interface to this C wrapper. For
example, to print an int value using printf,
create a C function printfi that takes two arguments, a
pointer to a string and an int, and calls printf.
Then in the Ada program, use pragma Import to
interface to printfi.
It may work on some platforms to directly interface to
a varargs function by providing a specific Ada profile
for a a particular call. However, this does not work on
all platforms, since there is no guarantee that the
calling sequence for a two argument normal C function
is the same as for calling a varargs C function with
the same two arguments.
Default
External
CPP
Fortran
Intrinsic
type Distance is new Long_Float; type Time is new Long_Float; type Velocity is new Long_Float; function "/" (D : Distance; T : Time) return Velocity; pragma Import (Intrinsic, "/"); |
This common idiom is often programmed with a generic definition and an explicit body. The pragma makes it simpler to introduce such declarations. It incurs no overhead in compilation time or code size, because it is implemented as a single machine instruction.
Stdcall
DLL
Win32
Stubbed
Program_Error.
GNAT additionally provides a useful pragma Convention_Identifier
that can be used to parametrize conventions and allow additional synonyms
to be specified. For example if you have legacy code in which the convention
identifier Fortran77 was used for Fortran, you can use the configuration
pragma:
pragma Convention_Identifier (Fortran77, Fortran); |
And from now on the identifier Fortran77 may be used as a convention
identifier (for example in an Import pragma) with the same
meaning as Fortran.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
A programmer inexperienced with mixed-language development may find that building an application containing both Ada and C++ code can be a challenge. As a matter of fact, interfacing with C++ has not been standardized in the Ada 95 Reference Manual due to the immaturity of -- and lack of standards for -- C++ at the time. This section gives a few hints that should make this task easier. The first section addresses the differences regarding interfacing with C. The second section looks into the delicate problem of linking the complete application from its Ada and C++ parts. The last section gives some hints on how the GNAT run time can be adapted in order to allow inter-language dispatching with a new C++ compiler.
2.11.1 Interfacing to C++ 2.11.2 Linking a Mixed C++ & Ada Program 2.11.3 A Simple Example 2.11.4 Adapting the Run Time to a New C++ Compiler
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
GNAT supports interfacing with C++ compilers generating code that is compatible with the standard Application Binary Interface of the given platform.
Interfacing can be done at 3 levels: simple data, subprograms, and classes. In the first two cases, GNAT offers a specific Convention CPP that behaves exactly like Convention C. Usually, C++ mangles the names of subprograms, and currently, GNAT does not provide any help to solve the demangling problem. This problem can be addressed in two ways:
extern "C" syntax.
Interfacing at the class level can be achieved by using the GNAT specific
pragmas such as CPP_Class and CPP_Virtual. See the GNAT
Reference Manual for additional information.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Usually the linker of the C++ development system must be used to link mixed applications because most C++ systems will resolve elaboration issues (such as calling constructors on global class instances) transparently during the link phase. GNAT has been adapted to ease the use of a foreign linker for the last phase. Three cases can be considered:
c++. Note that this setup is not very common because it
may involve recompiling the whole GCC tree from sources, which makes it
harder to upgrade the compilation system for one language without
destabilizing the other.
$ c++ -c file1.C $ c++ -c file2.C $ gnatmake ada_unit -largs file1.o file2.o --LINK=c++ |
$ gnatbind ada_unit $ gnatlink -v -v ada_unit file1.o file2.o --LINK=c++ |
$ cat ./my_script #!/bin/sh unset BINUTILS_ROOT unset GCC_ROOT c++ $* $ gnatlink -v -v ada_unit file1.o file2.o --LINK=./my_script |
If the setjmp/longjmp exception mechanism is used, only the paths
to the libgcc libraries are required:
$ cat ./my_script #!/bin/sh CC $* `gcc -print-file-name=libgcc.a` `gcc -print-file-name=libgcc_eh.a` $ gnatlink ada_unit file1.o file2.o --LINK=./my_script |
Where CC is the name of the non-GNU C++ compiler.
If the zero cost exception mechanism is used, and the platform
supports automatic registration of exception tables (e.g. Solaris or IRIX),
paths to more objects are required:
$ cat ./my_script #!/bin/sh CC `gcc -print-file-name=crtbegin.o` $* \ `gcc -print-file-name=libgcc.a` `gcc -print-file-name=libgcc_eh.a` \ `gcc -print-file-name=crtend.o` $ gnatlink ada_unit file1.o file2.o --LINK=./my_script |
If the zero cost exception mechanism is used, and the platform
doesn't support automatic registration of exception tables (e.g. HP-UX,
Tru64 or AIX), the simple approach described above will not work and
a pre-linking phase using GNAT will be necessary.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Here are the compilation commands:
$ gnatmake -c simple_cpp_interface
$ c++ -c cpp_main.C
$ c++ -c ex7.C
$ gnatbind -n simple_cpp_interface
$ gnatlink simple_cpp_interface -o cpp_main --LINK=$(CPLUSPLUS)
-lstdc++ ex7.o cpp_main.o
|
Here are the corresponding sources:
//cpp_main.C
#include "ex7.h"
extern "C" {
void adainit (void);
void adafinal (void);
void method1 (A *t);
}
void method1 (A *t)
{
t->method1 ();
}
int main ()
{
A obj;
adainit ();
obj.method2 (3030);
adafinal ();
}
//ex7.h
class Origin {
public:
int o_value;
};
class A : public Origin {
public:
void method1 (void);
void method2 (int v);
A();
int a_value;
};
//ex7.C
#include "ex7.h"
#include <stdio.h>
extern "C" { void ada_method2 (A *t, int v);}
void A::method1 (void)
{
a_value = 2020;
printf ("in A::method1, a_value = %d \n",a_value);
}
void A::method2 (int v)
{
ada_method2 (this, v);
printf ("in A::method2, a_value = %d \n",a_value);
}
A::A(void)
{
a_value = 1010;
printf ("in A::A, a_value = %d \n",a_value);
}
-- Ada sources
package body Simple_Cpp_Interface is
procedure Ada_Method2 (This : in out A; V : Integer) is
begin
Method1 (This);
This.A_Value := V;
end Ada_Method2;
end Simple_Cpp_Interface;
package Simple_Cpp_Interface is
type A is limited
record
O_Value : Integer;
A_Value : Integer;
end record;
pragma Convention (C, A);
procedure Method1 (This : in out A);
pragma Import (C, Method1);
procedure Ada_Method2 (This : in out A; V : Integer);
pragma Export (C, Ada_Method2);
end Simple_Cpp_Interface;
|
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
Interfaces.CPP. The default version of this file is adapted to
the GNU C++ compiler. Internal knowledge of the virtual
table layout used by the new C++ compiler is needed to configure
properly this unit. The Interface of this unit is known by the compiler
and cannot be changed except for the value of the constants defining the
characteristics of the virtual table: CPP_DT_Prologue_Size, CPP_DT_Entry_Size,
CPP_TSD_Prologue_Size, CPP_TSD_Entry_Size. Read comments in the source
of this unit for more details.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
The GNAT model of compilation is close to the C and C++ models. You can
think of Ada specs as corresponding to header files in C. As in C, you
don't need to compile specs; they are compiled when they are used. The
Ada with is similar in effect to the #include of a C
header.
One notable difference is that, in Ada, you may compile specs separately to check them for semantic and syntactic accuracy. This is not always possible with C headers because they are fragments of programs that have less specific syntactic or semantic rules.
The other major difference is the requirement for running the binder, which performs two important functions. First, it checks for consistency. In C or C++, the only defense against assembling inconsistent programs lies outside the compiler, in a makefile, for example. The binder satisfies the Ada requirement that it be impossible to construct an inconsistent program when the compiler is used in normal mode.
The other important function of the binder is to deal with elaboration
issues. There are also elaboration issues in C++ that are handled
automatically. This automatic handling has the advantage of being
simpler to use, but the C++ programmer has no control over elaboration.
Where gnatbind might complain there was no valid order of
elaboration, a C++ compiler would simply construct a program that
malfunctioned at run time.
| [ < ] | [ > ] | [ << ] | [ Up ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |
This section is intended to be useful to Ada programmers who have previously used an Ada compiler implementing the traditional Ada library model, as described in the Ada 95 Language Reference Manual. If you have not used such a system, please go on to the next section.
In GNAT, there is no library in the normal sense. Instead, the set of source files themselves acts as the library. Compiling Ada programs does not generate any centralized information, but rather an object file and a ALI file, which are of interest only to the binder and linker. In a traditional system, the compiler reads information not only from the source file being compiled, but also from the centralized library. This means that the effect of a compilation depends on what has been previously compiled. In particular:
with'ed, the unit seen by the compiler corresponds
to the version of the unit most recently compiled into the library.
In GNAT, compiling one unit never affects the compilation of any other units because the compiler reads only source files. Only changes to source files can affect the results of a compilation. In particular:
with'ed, the unit seen by the compiler corresponds
to the source version of the unit that is currently accessible to the
compiler.
The most important result of these differences is that order of compilation is never significant in GNAT. There is no situation in which one is required to do one compilation before another. What shows up as order of compilation requirements in the traditional Ada library becomes, in GNAT, simple source dependencies; in other words, there is only a set of rules saying what source files must be present when a file is compiled.
| [ << ] | [ >> ] | [Top] | [Contents] | [Index] | [ ? ] |