-- The Ada Structured Library - A set of container classes and general
--   tools for use with Ada95.
-- Copyright (C) 1998-1999  Corey Minyard (minyard@acm.org)
--
-- This library is free software; you can redistribute it and/or modify it
-- under the terms of the GNU General Public License as published by the
-- Free Software Foundation; either version 2 of the License, or (at your
-- option) any later version.
--
-- This library is distributed in the hope that it will be useful, but
-- WITHOUT ANY WARRANTY; without even the implied warranty of
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
-- General Public License for more details.
--
-- You should have received a copy of the GNU General Public License along
-- with this library; if not, write to the Free Software Foundation, Inc.,
-- 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
--
-- As a special exception, if other files instantiate generics from this
-- unit, or you link this unit with other files to produce an executable,
-- this unit does not by itself cause the resulting executable to be
-- covered by the GNU General Public License.  This exception does not
-- however invalidate any other reasons why the executable file might be
-- covered by the GNU Public License.
--

with Ada.Task_Identification; use type Ada.Task_Identification.Task_Id;

package body Asl.Semaphore.Nested is

   ------------------------------------------------------------------------
   procedure Take (O : in out Object) is
   begin
      O.The_Mutex.Wait;
   end Take;

   ------------------------------------------------------------------------
   procedure Give (O : in out Object) is
   begin
      O.The_Mutex.Release;
   end Give;

   ------------------------------------------------------------------------
   procedure Try_To_Take (O       : in out Object;
                          Success : out Boolean;
                          Timeout : in Duration := 0.0) is
   begin
      select
         O.The_Mutex.Wait;
         Success := True;
      or
         delay Timeout;
         Success := False;
      end select;
   end Try_To_Take;

   ------------------------------------------------------------------------
   ------------------------------------------------------------------------
   protected body Mutex is

      ---------------------------------------------------------------------
      -- Let the task in if no other task has the semaphore or if the
      -- calling task already owns the semaphore.
      entry Wait when ((Count = 0) or (Task_Ident.Current_Task = Owner)) is
      begin
         if (Count = 0) then
            Owner := Wait'Caller;
         end if;
         Count := Count + 1;
      end Wait;

      ---------------------------------------------------------------------
      procedure Release is
      begin
         if (Task_Ident.Current_Task /= Owner) then
            raise Tasking_Error;
         end if;

         Count := Count - 1;
         if (Count = 0) then
            Owner := Task_Ident.Null_Task_Id;
         end if;
      end Release;

   end Mutex;

end Asl.Semaphore.Nested;